***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 15, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5568A-AU     drain  gate  source
Lg     gate   g1   2.2n
Ld     drain  d1   100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     0.23
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=49.7  VTO=2.56  LEVEL=3  VMAX=1.2e5  ETA=0  gamma=1.2)
Rd     d1    d2    7.93m TC=6.2m,1.3e-5
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=66     TBV1=3.67e-4   TBV2=-2.3e-7  CJO=6.20e-10  M=0.5  VJ=6.25)
Rsp     s2    s3     0.65
Dbd1     s3    d2    Dbt1
.MODEL     Dbt1    D(BV=1000   CJO=0.41e-9   M=0.25   VJ=2.5)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=6.13e-16  N=0.78  RS=0.04u  EG=1.160  TT=30n  ikf=0.449)
Rdiode  d1  21    3.44m TC=2.2m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   3.20e-10
.MODEL     DGD    D(M=1.574   CJO=3.20e-10   VJ=7.077)
Rpar      b    d2   1Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    7.61e-10
.ENDS
*$
